Let us follow the required steps:

1. The top-level CMakeLists.txt defines the minimum CMake version, project name, and supported language, and requires the C++11 standard:

cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  
project(recipe-01 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

2. We further define binary and library paths according to GNU standards:

include(GNUInstallDirs)

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY
  ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR})
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY
  ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR})
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY
  ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR})

3. And finally, we use add_subdirectory calls to structure our CMake code into src/CMakeLists.txt and tests/CMakeLists.txt parts. We also enable testing:

add_subdirectory(src)

enable_testing()
add_subdirectory(tests)

4. The src/CMakeLists.txt file defines the source code targets:

set(CMAKE_INCLUDE_CURRENT_DIR_IN_INTERFACE ON)
  
add_library(sum_integers sum_integers.cpp)

add_executable(sum_up main.cpp)

target_link_libraries(sum_up sum_integers)

5. In tests/CMakeLists.txt, we first build and link the cpp_test executable:

add_executable(cpp_test test.cpp)
target_link_libraries(cpp_test sum_integers)

6. We then define a new macro, add_catch_test, which we will discuss later:

macro(add_catch_test _name _cost)
  math(EXPR num_macro_calls "${num_macro_calls} + 1")
  message(STATUS "add_catch_test called with ${ARGC} arguments: ${ARGV}")

  set(_argn "${ARGN}")
  if(_argn)
    message(STATUS "oops - macro received argument(s) we did not expect: ${ARGN}")
  endif()

  add_test(
    NAME
      ${_name}
    COMMAND
      $<TARGET_FILE:cpp_test>
      [${_name}] --success --out
      ${PROJECT_BINARY_DIR}/tests/${_name}.log --durations yes
    WORKING_DIRECTORY
      ${CMAKE_CURRENT_BINARY_DIR}
    )

  set_tests_properties(
    ${_name}
    PROPERTIES
      COST ${_cost}
    )
endmacro()

7. Finally, we define two tests using add_catch_test and in addition, we set and print the value of a variable:

set(num_macro_calls 0)

add_catch_test(short 1.5)
add_catch_test(long 2.5 extra_argument)

message(STATUS "in total there were ${num_macro_calls} calls to add_catch_test")

8. Now, we are ready to test it out. First, we configure the project (the interesting output lines are shown):

$ mkdir -p build
$ cd build
$ cmake ..

-- ...
-- add_catch_test called with 2 arguments: short;1.5
-- add_catch_test called with 3 arguments: long;2.5;extra_argument
-- oops - macro received argument(s) we did not expect: extra_argument
-- in total there were 2 calls to add_catch_test
-- ...

9. Finally, we build and run the tests:

$ cmake --build .
$ ctest

10. Observe that the long test is started first:

    Start 2: long
1/2 Test #2: long ............................. Passed 0.00 sec
    Start 1: short
2/2 Test #1: short ............................ Passed 0.00 sec

100% tests passed, 0 tests failed out of 2